tellraw @s [{"text":"▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣","color":"#4a4a4a"}]
tellraw @s ["",{"text":"✧ Skill points: ","color":"#e6e4a3"},{"score":{"name":"@s","objective":"hatred_skill_point_count"},"bold":true,"color":"#e6e4a3","shadow_color":-13549763}," ",{"text":"✧","color":"#e6e4a3"}]
tellraw @s ["",{"text":"♕ Overwhelm levels: ","color":"#bf5a5a"},{"score":{"name":"@s","objective":"hatred_skill_overwhelm"},"color":"#ec7474"}," ",{"text":"-","color":"#4a4a4a"}," ",{"text":"[","color":"#bce6e5"},{"text":"Add point","color":"#bce6e5","click_event":{"action":"run_command","command":"/function hatred:func/level/book/book_add_overwhelm"},"hover_event":{"action":"show_text","value":[{"text":"No level cap","color":"#ddda88"}]}},{"text":"]","color":"#bce6e5"}]
#health
scoreboard players operation whole hatred_misc = @s hatred_skill_overwhelm
scoreboard players operation frac hatred_misc = @s hatred_skill_overwhelm

scoreboard players operation whole hatred_misc /= two hatred_misc

scoreboard players operation frac hatred_misc %= two hatred_misc
scoreboard players operation frac hatred_misc *= five hatred_misc
tellraw @s [{"text":"- Bonus health: ","color":"#A24E4E"},{"score":{"name":"whole","objective":"hatred_misc"},"color":"#a6e09f"},{"text":".","color":"#7fad7b","shadow_color":-13352652},{"score":{"name":"frac","objective":"hatred_misc"},"color":"#7fad7b","shadow_color":-13352652}]

#damage
scoreboard players operation temp hatred_core = @s hatred_skill_overwhelm
tellraw @s [{"text":"- Bonus melee damage: ","color":"#A24E4E"},{"score":{"name":"temp","objective":"hatred_core"},"color":"#dd2727"},{"text":"%","color":"#a71111"}]



tellraw @s [{"text":"------------------------------","color":"#4d4c4c"}]


tellraw @s ["",{"text":"◔ Acceleration levels: ","color":"#91b1b1"},{"score":{"name":"@s","objective":"hatred_skill_acceleration"},"color":"#a5caca"}," ",{"text":"-","color":"#4a4a4a"}," ",{"text":"[","color":"#bce6e5"},{"text":"Add point","color":"#bce6e5","click_event":{"action":"run_command","command":"/function hatred:func/level/book/book_add_acceleration"},"hover_event":{"action":"show_text","value":[{"text":"Maximum level: 30","color":"#eb8424"}]}},{"text":"]","color":"#bce6e5"}]
#speed
scoreboard players operation whole hatred_misc = @s hatred_skill_acceleration
scoreboard players operation frac hatred_misc = @s hatred_skill_acceleration
scoreboard players operation whole hatred_misc /= two hatred_misc
scoreboard players operation frac hatred_misc %= two hatred_misc
scoreboard players operation frac hatred_misc *= five hatred_misc
tellraw @s [{"text":"- Bonus speed:","color":"#7d9797"},{"text":" ","color":"#91b1b1"},{"score":{"name":"whole","objective":"hatred_misc"},"color":"#c4ded6"},{"text":".","color":"#98aea7"},{"score":{"name":"frac","objective":"hatred_misc"},"color":"#98aea7"},{"text":"%","color":"#98aea7"}]
#atk speed
scoreboard players operation temp hatred_core = @s hatred_skill_acceleration
tellraw @s [{"text":"- Bonus attack speed:","color":"#7d9797"},{"text":" ","color":"#91b1b1"},{"score":{"name":"temp","objective":"hatred_core"},"color":"#c4ded6"},{"text":"%","color":"#98aea7"}]





tellraw @s [{"text":"------------------------------","color":"#4d4c4c"}]


tellraw @s ["",{"text":"♡ Fortitude levels: ","color":"#8bac8e"},{"score":{"name":"@s","objective":"hatred_skill_fortitude"},"color":"#91ba96"}," ",{"text":"-","color":"#4a4a4a"}," ",{"text":"[","color":"#bce6e5"},{"text":"Add point","color":"#bce6e5","click_event":{"action":"run_command","command":"/function hatred:func/level/book/book_add_fortitude"},"hover_event":{"action":"show_text","value":[{"text":"Maximum level: 50","color":"#d324eb"}]}},{"text":"]","color":"#bce6e5"}]
#armor
scoreboard players operation whole hatred_misc = @s hatred_skill_fortitude
scoreboard players operation whole hatred_misc *= twelve hatred_misc
scoreboard players operation frac hatred_misc = whole hatred_misc
scoreboard players operation whole hatred_misc /= hundred hatred_misc
scoreboard players operation frac hatred_misc %= hundred hatred_misc
execute if score frac hatred_misc matches 0..9 run tellraw @s [{"text":"- Bonus armor: ","color":"#7d9780"},{"score":{"name":"whole","objective":"hatred_misc"},"color":"#a8aacd"},{"text":".0","color":"#7c7e9c"},{"score":{"name":"frac","objective":"hatred_misc"},"color":"#7c7e9c"}]
execute if score frac hatred_misc matches 10.. run tellraw @s [{"text":"- Bonus armor: ","color":"#7d9780"},{"score":{"name":"whole","objective":"hatred_misc"},"color":"#a8aacd"},{"text":".","color":"#7c7e9c"},{"score":{"name":"frac","objective":"hatred_misc"},"color":"#7c7e9c"}]
#armor toughness
scoreboard players operation whole hatred_misc = @s hatred_skill_fortitude
scoreboard players operation whole hatred_misc *= two hatred_misc
scoreboard players operation frac hatred_misc = whole hatred_misc
scoreboard players operation whole hatred_misc /= ten hatred_misc
scoreboard players operation frac hatred_misc %= ten hatred_misc
tellraw @s [{"text":"- Bonus armor toughness: ","color":"#7d9780"},{"score":{"name":"whole","objective":"hatred_misc"},"color":"#d5af95"},{"text":".","color":"#a0826e"},{"score":{"name":"frac","objective":"hatred_misc"},"color":"#a0826e"}]





tellraw @s [{"text":"------------------------------","color":"#4d4c4c"}]



tellraw @s ["",{"text":"♰ Influence levels: ","color":"#a26db0"},{"score":{"name":"@s","objective":"hatred_skill_influence"},"color":"#c98bda"}," ",{"text":"-","color":"#4a4a4a"}," ",{"text":"[","color":"#bce6e5"},{"text":"Add point","color":"#bce6e5","click_event":{"action":"run_command","command":"/function hatred:func/level/book/book_add_influence"},"hover_event":{"action":"show_text","value":[{"text":"Maximum level: 30","color":"#d324eb"}]}},{"text":"]","color":"#bce6e5"}]
#entity reach
scoreboard players operation whole hatred_misc = @s hatred_skill_influence
scoreboard players operation frac hatred_misc = @s hatred_skill_influence
scoreboard players operation whole hatred_misc /= hundred hatred_misc
scoreboard players operation frac hatred_misc %= hundred hatred_misc
execute if score frac hatred_misc matches 0..9 run tellraw @s [{"text":"- Bonus attack reach: ","color":"#855a90"},{"score":{"name":"whole","objective":"hatred_misc"},"color":"#db8fbb"},{"text":".0","color":"#ab7393"},{"score":{"name":"frac","objective":"hatred_misc"},"color":"#ab7393"}]
execute if score frac hatred_misc matches 10.. run tellraw @s [{"text":"- Bonus attack reach: ","color":"#855a90"},{"score":{"name":"whole","objective":"hatred_misc"},"color":"#db8fbb"},{"text":".","color":"#ab7393"},{"score":{"name":"frac","objective":"hatred_misc"},"color":"#ab7393"}]

scoreboard players operation temp hatred_misc = @s hatred_skill_influence
scoreboard players operation temp hatred_misc *= four hatred_misc

scoreboard players operation whole hatred_misc = temp hatred_misc
scoreboard players operation frac hatred_misc = temp hatred_misc
scoreboard players operation whole hatred_misc /= hundred hatred_misc
scoreboard players operation frac hatred_misc %= hundred hatred_misc
execute if score frac hatred_misc matches 0..9 run tellraw @s [{"text":"- Bonus block reach: ","color":"#855a90"},{"score":{"name":"whole","objective":"hatred_misc"},"color":"#b18577"},{"text":".0","color":"#89675d"},{"score":{"name":"frac","objective":"hatred_misc"},"color":"#89675d"}]
execute if score frac hatred_misc matches 10.. run tellraw @s [{"text":"- Bonus block reach: ","color":"#855a90"},{"score":{"name":"whole","objective":"hatred_misc"},"color":"#b18577"},{"text":".","color":"#89675d"},{"score":{"name":"frac","objective":"hatred_misc"},"color":"#89675d"}]

scoreboard players operation whole hatred_misc = @s hatred_skill_influence
tellraw @s [{"text":"- Bonus block breaking speed: ","color":"#855a90"},{"score":{"name":"whole","objective":"hatred_misc"},"color":"#e9f0b2"},{"text":"%","color":"#cdcc9d"}]
tellraw @s [" "]
tellraw @s [{"text":"Reset point allocation:","color":"#92ba91"},{"text":" [","color":"#d71919"},{"text":"Reset","color":"#d71919","click_event":{"action":"run_command","command":"/function hatred:func/level/book/book_reset_point"}},{"text":"]","color":"#d71919"}]
tellraw @s [{"text":"▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣▣","color":"#4a4a4a"}]