## Custom blocks
execute if entity @s[type=item_display,tag=vb.custom_block] run function vb:tick_entity/custom_block/main

## Interactions
execute if entity @s[type=interaction,tag=vb.custom_block_interaction] if data entity @s interaction run function vb:tick_entity/custom_block_interaction/main

## Modified mobs
execute if entity @s[type=#vb:modified_mob] run function vb:tick_entity/modified_mob/main

## Custom mobs
execute if entity @s[type=#vb:custom_mob_base,tag=vb.custom_mob] run function vb:tick_entity/custom_mob/main

## Despawn
execute if entity @s[tag=vb.despawn_after_time] run function vb:tick_entity/despawn_after_time

## Name tags
# Silence
execute if entity @s[name='Silence'] run tag @s add vb.name_tag.silence
execute if entity @s[tag=vb.name_tag.silence] run function vb:tick_entity/name_tag/silence
# jeb_
execute if entity @s[name='jeb_',type=minecraft:shulker] run tag @s add vb.name_tag.jeb_
execute if entity @s[tag=vb.name_tag.jeb_] run function vb:tick_entity/name_tag/jeb_
# The Killer Bunny
execute if entity @s[name='The Killer Bunny',type=minecraft:rabbit] run tag @s add vb.name_tag.the_killer_bunny
execute if entity @s[tag=vb.name_tag.the_killer_bunny] run function vb:tick_entity/name_tag/the_killer_bunny
# Ethel
execute if entity @s[name='Ethel',type=minecraft:cat] run tag @s add vb.name_tag.ethel
execute if entity @s[tag=vb.name_tag.ethel] run function vb:tick_entity/name_tag/ethel

## Custom sounds
execute if entity @s[type=#vb:custom_mob_base,tag=vb.custom_sounds] run function vb:tick_entity/custom_sounds