
# -> Item frame with map wisdom gain
execute as @e[type=item_frame] \
    if items entity @s contents filled_map \
    at @s run \
        tag @a[tag=!OverlyRealistic.Player.IsDeity,distance=..20] add OverlyRealistic.Player.IsNearMapItemFrame

# -> Operate on players
execute as @a[tag=!OverlyRealistic.Player.IsDeity] at @s run \
    function overly_realistic:general/main_loops/main_loop_6000t_operate

# -> Spider cobweb placements
execute at @e[type=spider,limit=32,sort=arbitrary] \
    if predicate overly_realistic:animal/random_spider_cobweb_rng run \
        fill ~ ~ ~ ~ ~ ~ cobweb replace #air

# -> Schedule animal operations
schedule function overly_realistic:animals/operations/animal_operations_6001t 1t

# -> Function tag
function #overly_realistic:general_loops/main_6000t


# -> Loop (5 mins)
schedule function overly_realistic:general/main_loops/main_loop_6000t 6000t