
# -> Reset adv trigger
advancement revoke @s only overly_realistic:player/player_get_hurt_potent_fire

# -> Bleeding RNG
execute if predicate overly_realistic:player/damage/direct_damage_bleeding_rng run \
    function overly_realistic:players/bleeding/start_bleeding

# -> Mental health decrease RNG
execute if predicate overly_realistic:player/damage/potent_direct_damage_rng run \
    function overly_realistic:players/mental_health/edit_mental_health {type:"remove",value:3}

# -> Particles
particle minecraft:campfire_signal_smoke ~ ~ ~ 0 0.8 0 0.03 35 normal @a

# -> Check for lava
execute if block ~ ~ ~ lava run \
    return run \
        attribute @s burning_time modifier add overly_realistic:physical_trauma_potent_fire_damage_burn 30.0 add_value
execute if block ~ ~1 ~ lava run \
    return run \
        attribute @s burning_time modifier add overly_realistic:physical_trauma_potent_fire_damage_burn 30.0 add_value

# -> Physical trauma RNG
execute if predicate overly_realistic:player/damage/potent_direct_damage_rng run \
    return fail

# -> Decrease thirst
execute store result score #or.random_thirst OverlyRealistic.General.ArbitraryData run \
    random value 3..10
scoreboard players operation @a OverlyRealistic.Player.Stats.Thirst -= #or.random_thirst OverlyRealistic.General.ArbitraryData

# -> Apply attributes
attribute @s burning_time modifier add overly_realistic:physical_trauma_potent_fire_damage_burn 10.0 add_value

# -> Advancement
advancement grant @s only overly_realistic:advancements/livelyhood/sticks_and_stones
