
# -> Bucket
execute if items entity @s weapon.mainhand bucket run \
    return run \
        item replace entity @s weapon.mainhand with water_bucket

# -> Increase cookery XP
execute if score #or.equation_part_2 OverlyRealistic.General.ArbitraryData matches 1.. run \
    function overly_realistic:players/wisdom/cookery/add_to_skill_xp_c_prepare_food_in_basket

# -> Bottle (sweet berry drink)
execute if items entity @s weapon.mainhand glass_bottle \
    if score #or.equation_part_2 OverlyRealistic.General.ArbitraryData matches 2 run \
        return run \
            loot replace entity @s weapon.mainhand loot overly_realistic:items/sweet_berry_drink

# -> Bottle (sweetened sweet berry drink)
execute if items entity @s weapon.mainhand glass_bottle \
    if score #or.equation_part_2 OverlyRealistic.General.ArbitraryData matches 3 run \
        return run \
            loot replace entity @s weapon.mainhand loot overly_realistic:items/sweetened_sweet_berry_drink

# -> Bottle (dirt water)
execute if items entity @s weapon.mainhand glass_bottle \
    if score #or.equation_part_2 OverlyRealistic.General.ArbitraryData matches 0 run \
        return run \
            loot replace entity @s weapon.mainhand loot overly_realistic:items/dirty_water

# -> Bottle (clean water)
execute if items entity @s weapon.mainhand glass_bottle \
    if score #or.equation_part_2 OverlyRealistic.General.ArbitraryData matches 1 run \
        return run \
            loot replace entity @s weapon.mainhand loot overly_realistic:items/clean_water
