
# -> If player is holding a hoe while skilled in husbandry then add reach
attribute @s block_interaction_range modifier remove overly_realistic:wisdom_husbandry_skill_buff
execute if items entity @s[scores={OverlyRealistic.Player.WisdomStats.Husbandry=3..4}] weapon.mainhand #hoes run \
    attribute @s block_interaction_range modifier add overly_realistic:wisdom_husbandry_skill_buff 2.0 add_value
execute if items entity @s[scores={OverlyRealistic.Player.WisdomStats.Husbandry=5..}] weapon.mainhand #hoes run \
    attribute @s block_interaction_range modifier add overly_realistic:wisdom_husbandry_skill_buff 3.5 add_value

# -> Remove snow slowness attribute
attribute @s movement_speed modifier remove overly_realistic:snow_slowness_movement_speed

# -> If player has snow boots on then return
execute if items entity @s armor.feet leather_boots[custom_data~{IsSnowBoots:1b}] run \
    return fail

# -> If player is standing on snow then add slowness attribute
execute if block ~ ~ ~ snow run \
    attribute @s movement_speed modifier add overly_realistic:snow_slowness_movement_speed -0.03 add_value
execute if block ~ ~-0.5 ~ #overly_realistic:is_snowy run \
    attribute @s movement_speed modifier add overly_realistic:snow_slowness_movement_speed -0.03 add_value
