
# -> Current block
execute if block ~ ~ ~ #overly_realistic:flammable \
    if block ~ ~1 ~ #air run \
        return run \
            fill ~ ~1 ~ ~ ~1 ~ fire replace air

# -> Non-air check
execute unless block ~ ~ ~ #air run \
    return fail

# -> Up/down
execute if block ~ ~1 ~ #overly_realistic:flammable run \
    return run \
        fill ~ ~ ~ ~ ~ ~ fire replace air
execute if block ~ ~-1 ~ #overly_realistic:flammable run \
    return run \
        fill ~ ~ ~ ~ ~ ~ fire replace air

# -> Sides
execute if block ~ ~ ~1 #overly_realistic:flammable run \
    return run \
        fill ~ ~ ~ ~ ~ ~ fire replace air
execute if block ~ ~ ~-1 #overly_realistic:flammable run \
    return run \
        fill ~ ~ ~ ~ ~ ~ fire replace air
execute if block ~1 ~ ~ #overly_realistic:flammable run \
    return run \
        fill ~ ~ ~ ~ ~ ~ fire replace air
execute if block ~-1 ~ ~ #overly_realistic:flammable run \
    return run \
        fill ~ ~ ~ ~ ~ ~ fire replace air
