
# -> If player is shifting then drop items
execute if score @s OverlyRealistic.PredicateValue.IsSneaking matches 1 run \
    return run \
        scoreboard players set #or.wooden_rack_interaction_type OverlyRealistic.General.ArbitraryData 3

# -> Store item
item replace entity 00000001-0000-002b-0000-00010000002b contents from entity @s weapon.mainhand overly_realistic:items/set_1_count

# -> Check if wood items are in the player's offhand
#execute if items entity 00000001-0000-002b-0000-00010000002b contents #overly_realistic:wooden_rack_wood_interactions run \
    return run \
        scoreboard players set #or.wooden_rack_interaction_type OverlyRealistic.General.ArbitraryData 1

# -> If wooden rack has gory hide and player is holding an item then set value
execute if score #or.wooden_rack_has_gory_hide OverlyRealistic.General.ArbitraryData matches 1 \
    if function overly_realistic:general/custom_blocks/gory_hide/player_interact_with_gory_hide run \
        return run \
            scoreboard players set #or.wooden_rack_interaction_type OverlyRealistic.General.ArbitraryData 5

# -> If player has gory hide then set value
execute if items entity @s weapon.mainhand *[custom_data~{or_is_gory_hide:1b}] run \
    return run \
        scoreboard players set #or.wooden_rack_interaction_type OverlyRealistic.General.ArbitraryData 4

# -> If player has doused hide then set value
execute if items entity @s weapon.mainhand *[custom_data~{or_is_doused_hide:1b}] run \
    return run \
        scoreboard players set #or.wooden_rack_interaction_type OverlyRealistic.General.ArbitraryData 6

# -> If player has hide then set value
execute if items entity @s weapon.mainhand rabbit_hide run \
    return run \
        scoreboard players set #or.wooden_rack_interaction_type OverlyRealistic.General.ArbitraryData 2
