
# -> Set data
data modify entity @s IsImmuneToZombification set value 1b

# -> Set targeter team
team join overly_realistic.targeters @s

# -> Tag entity
tag @s add OverlyRealistic.CommonAnimalChecked
tag @s add OverlyRealistic.CommonAnimalAggressive

# -> Apply vars
execute store result score @s OverlyRealistic.Animal.Stamina run \
    random value 100..900

# -> Apply modifiers
attribute @s max_health modifier add overly_realistic:animal_default_max_health 50 add_value
attribute @s knockback_resistance modifier add overly_realistic:animal_default_knockback_resistance 0.05 add_value
attribute @s movement_speed modifier add overly_realistic:animal_default_movement_speed 0.015 add_value

effect give @s regeneration 3 255 true

# -> Get randomized array entry
execute store result storage overly_realistic:temp_values generic_value_0 int 1 run \
    random value 0..9

# -> Apply genetics
function overly_realistic:animals/genetics/get_animal_genetics_entry with storage overly_realistic:temp_values
