
# -> Operate on players
execute as @a run \
    function overly_realistic:general/main_loops/main_loop_1200t_operate

# -> Remove animal holders which are not on animals
kill @e\
    [\
        tag=OverlyRealistic.Animal.AnimalHolderEntity,\
        type=#overly_realistic:animal_holder_entities,\
        predicate=overly_realistic:animal/animal_targeter_ent_can_remove,\
        x=0\
    ]

# -> Function tag
function #overly_realistic:general_loops/main_1200t

# -> Loop (1 minute)
schedule function overly_realistic:general/main_loops/main_loop_1200t 1200t

# -> If 'Harder Hunger' is disabled, then return
execute if score #or.setting.harder_hunger OverlyRealistic.Settings.ArbitrarySetting matches 0 run \
    return fail

# -> Schedule hunger applications
schedule function overly_realistic:general/hunger/from_main_loops/hunger_apply_1201t 1t
schedule function overly_realistic:general/hunger/from_main_loops/hunger_apply_1300t 100t
schedule function overly_realistic:general/hunger/from_main_loops/hunger_apply_1400t 200t
schedule function overly_realistic:general/hunger/from_main_loops/hunger_apply_1500t 300t
schedule function overly_realistic:general/hunger/from_main_loops/hunger_apply_1600t 400t
schedule function overly_realistic:general/hunger/from_main_loops/hunger_apply_1700t 500t
schedule function overly_realistic:general/hunger/from_main_loops/hunger_apply_1800t 600t
schedule function overly_realistic:general/hunger/from_main_loops/hunger_apply_1900t 700t

