
# -> If basket already has additionals of base type then return
execute if entity @s[tag=OverlyRealistic.Block.Basket_Status_HasAdditionalsBase] run \
    return fail

# -> Advancement
execute on target run \
    advancement grant @s only overly_realistic:advancements/basket_uses/toxicology

# -> Add to healthcare XP
execute on target run \
    function overly_realistic:players/wisdom/healthcare/add_to_skill_xp_c_make_poison_in_basket

# -> Create new display
summon minecraft:item_display ~ ~ ~ {Tags:["OverlyRealistic.Block.Basket_Display_PoisonBase","OverlyRealistic.Block.Basket_Display_IsAdditional"],item: {id: "minecraft:slime_block",components:{item_model:"overlyrealistic:blocks/basket_additionals/poison_additional_base"}}, transformation: {left_rotation: [0.0f, 0.0f, 0.0f, 1.0f], right_rotation: [0.0f, 0.0f, 0.0f, 1.0f], scale: [0.875f, 0.5625f, 0.875f], translation: [-0.4375f, -0.900f, -0.4375f]}}

# -> Attach new display
ride @n[type=item_display,tag=OverlyRealistic.Block.Basket_Display_PoisonBase,distance=..0.5] mount @s

# -> Tag ent
tag @s add OverlyRealistic.Block.Basket_Status_HasPoisonBase
tag @s add OverlyRealistic.Block.Basket_Status_HasAdditionalsBase

# -> Remove items
function overly_realistic:general/custom_blocks/basket/interactions/int_remove_all_items_no_drop
