
# -> Reset adv trigger
advancement revoke @s only overly_realistic:items/consumption/drink_dirty_water_from_hide_waterskin

# -> Hydration RNG
execute store result score #or.global OverlyRealistic.General.ArbitraryData run \
    random value 1..3
execute store result score #or.random_thirst_addition OverlyRealistic.General.ArbitraryData run \
    random value 3..5

# -> Thirst operate
execute if score #or.global OverlyRealistic.General.ArbitraryData matches 1 run \
    function overly_realistic:players/thirst/add_hydration_from_generic_randomized
scoreboard players set #or.central_value_set_thirst OverlyRealistic.General.ArbitraryData 23
execute if score #or.global OverlyRealistic.General.ArbitraryData matches 2 run \
    function overly_realistic:players/thirst/remove_hydration_from_generic

# -> Add pseudo-illness
effect give @s hunger 15 1 true
effect give @s nausea 8 0 true

# -> On RNG, give player an illness
execute if predicate overly_realistic:player/illness/hide_waterskin_illness_rng run \
    scoreboard players add @s OverlyRealistic.Player.FoodIllnessAmount 18
