
# -> Remove tag
tag @s remove OverlyRealistic.Player.TempBandagePlayer

# -> Mental health increase RNG
execute if predicate overly_realistic:player/damage/potent_direct_damage_rng run \
    function overly_realistic:players/mental_health/add_to_mental_health_by_1

# -> Sound
playsound minecraft:block.wool.step player @a ~ ~ ~ 0.5 2

# -> Set title
title @s times 0 15 0
title @s subtitle [{text:"[Bandaged Player]"}]

# -> Add to healthcare experience
function overly_realistic:players/wisdom/healthcare/add_to_skill_xp_c_bandage_other_player

# -> Operate on bandaged player
execute as @p[tag=!OverlyRealistic.Player.TempBandagePlayer,dx=1,dy=1,dz=1] run \
    function overly_realistic:players/operations/player_use_bandage_shifting_3rd_party

# -> Remove item
execute if items entity @s weapon.mainhand *[custom_data~{IsBandage:1b}] run \
    return run \
        item modify entity @s weapon.mainhand overly_realistic:multipurpose/remove_one_item
item modify entity @s weapon.offhand overly_realistic:multipurpose/remove_one_item
