
# -> Bucket
#execute if items entity @s weapon.mainhand bucket run \
    return run \
        item replace entity @s weapon.mainhand with water_bucket

# -> Increase cookery XP
execute if score #or.basket_contents_liquid_type OverlyRealistic.General.ArbitraryData matches 2..3 run \
    function overly_realistic:players/wisdom/cookery/add_to_skill_xp_c_prepare_food_in_basket

# -> Wooden Bucket
execute if items entity @s weapon.mainhand *[custom_data~{or_bucket_specific: "wooden_bucket"}] run \
    return run \
        function overly_realistic:general/custom_blocks/basket/interactions/get_water/player_get_water_with_wooden_bucket

# -> Iron Bucket
execute if items entity @s weapon.mainhand *[custom_data~{or_bucket_specific: "iron_bucket"}] run \
    return run \
        function overly_realistic:general/custom_blocks/basket/interactions/get_water/player_get_water_with_iron_bucket

# -> Bottle
execute unless items entity @s weapon.mainhand glass_bottle run \
    return fail

# -> Bottle (sweet berry drink)
execute if score #or.basket_contents_liquid_type OverlyRealistic.General.ArbitraryData matches 2 run \
    return run \
        loot replace entity @s weapon.mainhand loot overly_realistic:items/sweet_berry_drink

# -> Bottle (sweetened sweet berry drink)
execute if score #or.basket_contents_liquid_type OverlyRealistic.General.ArbitraryData matches 3 run \
    return run \
        loot replace entity @s weapon.mainhand loot overly_realistic:items/sweetened_sweet_berry_drink

# -> Bottle (dirt water)
execute if score #or.basket_contents_liquid_type OverlyRealistic.General.ArbitraryData matches 4 run \
    return run \
        loot replace entity @s weapon.mainhand loot overly_realistic:items/dirty_water

# -> Bottle (clean water)
execute if score #or.basket_contents_liquid_type OverlyRealistic.General.ArbitraryData matches 1 run \
    return run \
        loot replace entity @s weapon.mainhand loot overly_realistic:items/clean_water

# -> Bottle (sea water)
execute if score #or.basket_contents_liquid_type OverlyRealistic.General.ArbitraryData matches 5 run \
    return run \
        loot replace entity @s weapon.mainhand loot overly_realistic:items/sea_water
