
# -> Set frosted ice below
setblock ~ ~-1 ~ frosted_ice[age=1] replace

# -> Overall RNG
execute unless predicate overly_realistic:world/block_physics/ice_break_direction_rng run \
    return fail

# -> On RNG, set cardinal direction ice blocks as frosted ice
execute if block ~1 ~-1 ~ ice \
    if predicate overly_realistic:world/block_physics/ice_break_rng run \
        setblock ~1 ~-1 ~ frosted_ice[age=1] replace
execute if block ~ ~-1 ~1 ice \
    if predicate overly_realistic:world/block_physics/ice_break_rng run \
        setblock ~ ~-1 ~1 frosted_ice[age=1] replace
execute if block ~-1 ~-1 ~ ice \
    if predicate overly_realistic:world/block_physics/ice_break_rng run \
        setblock ~-1 ~-1 ~ frosted_ice[age=1] replace
execute if block ~ ~-1 ~-1 ice \
    if predicate overly_realistic:world/block_physics/ice_break_rng run \
        setblock ~ ~-1 ~-1 frosted_ice[age=1] replace

# -> Corners RNG
execute unless predicate overly_realistic:world/block_physics/ice_break_direction_rng run \
    return fail

# -> On RNG, set corner ice blocks as frosted ice
execute if block ~1 ~-1 ~1 ice \
    if predicate overly_realistic:world/block_physics/ice_break_rng run \
        setblock ~1 ~-1 ~1 frosted_ice[age=1] replace
execute if block ~-1 ~-1 ~-1 ice \
    if predicate overly_realistic:world/block_physics/ice_break_rng run \
        setblock ~-1 ~-1 ~-1 frosted_ice[age=1] replace
execute if block ~1 ~-1 ~-1 ice \
    if predicate overly_realistic:world/block_physics/ice_break_rng run \
        setblock ~1 ~-1 ~-1 frosted_ice[age=1] replace
execute if block ~-1 ~-1 ~1 ice \
    if predicate overly_realistic:world/block_physics/ice_break_rng run \
        setblock ~-1 ~-1 ~1 frosted_ice[age=1] replace
