
# -> Get random value for segment_amount blockstate
execute store result storage overly_realistic:temp_values generic_value_0 int 1 run \
    random value 1..4

# -> Get random value for facing blockstate
execute store result score #or.global OverlyRealistic.General.ArbitraryData run \
    random value 1..4

# -> Get facing blockstate
execute if score #or.global OverlyRealistic.General.ArbitraryData matches 1 run \
    data modify storage overly_realistic:temp_values temp_string_0 set value "north"
execute if score #or.global OverlyRealistic.General.ArbitraryData matches 2 run \
    data modify storage overly_realistic:temp_values temp_string_0 set value "south"
execute if score #or.global OverlyRealistic.General.ArbitraryData matches 3 run \
    data modify storage overly_realistic:temp_values temp_string_0 set value "east"
execute if score #or.global OverlyRealistic.General.ArbitraryData matches 4 run \
    data modify storage overly_realistic:temp_values temp_string_0 set value "west"

# -> Place leaf litter
function overly_realistic:general/random_events/random_event_3600t/leaf_litter_spread/place_leaf_litter with storage overly_realistic:temp_values