
# -> Get if world has multiple players
execute store result score #or.current_player_count OverlyRealistic.General.ArbitraryData run \
    list
execute if score #or.current_player_count OverlyRealistic.General.ArbitraryData matches 2.. run \
    scoreboard players set #or.world_has_been_played_in_multiplayer OverlyRealistic.General.ArbitraryData 1

# -> True survivor advancement check
execute unless score #or.world_has_been_played_in_multiplayer OverlyRealistic.General.ArbitraryData matches 1 run \
    advancement grant @a[scores={OverlyRealistic.Player.PlayedForSeconds_InGame=360000..}] only overly_realistic:advancements/overview/true_survivor

# -> Operate on players
execute as @a[tag=!OverlyRealistic.Player.IsDeity,tag=!OverlyRealistic.Player.IsGhost] at @s run \
    function overly_realistic:general/main_loops/main_loop_99t_operate

# -> Function tag
function #overly_realistic:general_loops/main_98t

# -> Loop (5 sec)
schedule function overly_realistic:general/main_loops/main_loop_98t 98t