
# -> Reset adv trigger
advancement revoke @s only overly_realistic:items/consumption/eat_cake

# -> Reset AteCake
scoreboard players reset @s OverlyRealistic.Player.AteCake

# -> Give saturation
effect give @s saturation 1 1 true

# -> Increase stamina
scoreboard players add @s OverlyRealistic.Player.Stats.Stamina 6

# -> Increase carbs
scoreboard players set #or.central_value_set_carbs OverlyRealistic.General.ArbitraryData 15
function overly_realistic:players/macronutrients/add_carbs

# -> Increase proteins
scoreboard players set #or.central_value_set_proteins OverlyRealistic.General.ArbitraryData 1
function overly_realistic:players/macronutrients/add_proteins

# -> Increase fats
scoreboard players set #or.central_value_set_fats OverlyRealistic.General.ArbitraryData 7
function overly_realistic:players/macronutrients/add_fats

# -> Sound
playsound entity.generic.eat player @a ~ ~0.5 ~ 0.5 1

# -> Particle
execute anchored eyes \
    positioned ^ ^ ^ \
    anchored feet run \
        particle block_crumble{block_state:"cake"} ^ ^ ^0.5 0.1 0.1 0.1 1 10 normal @a
