
# -> Sound
playsound minecraft:item.axe.strip block @a ~ ~ ~ 0.35 2

# -> Increase stone hatchet uses
scoreboard players add @s OverlyRealistic.Player.AxeStripUses 1

# -> If player is using a copper axe then add to uses
execute if items entity @s weapon.* *[custom_data~{or_tool_type:"axe",or_tool_material:"copper"}] run \
    scoreboard players add @s OverlyRealistic.Player.AxeStripUses 1

# -> If player is using an iron axe then add to uses
execute if items entity @s weapon.* *[custom_data~{or_tool_type:"axe",or_tool_material:"iron"}] run \
    scoreboard players add @s OverlyRealistic.Player.AxeStripUses 2

# -> Get log
loot replace entity 00000001-0000-002b-0000-00010000002b contents mine ~ ~ ~ netherite_axe[enchantments={silk_touch:1}]

# -> Store log name
data modify storage overly_realistic:temp_values temp_string_0 set value ""
data modify storage overly_realistic:temp_values temp_string_0 set string entity 00000001-0000-002b-0000-00010000002b item.id 10

# -> Particle
function overly_realistic:players/items/axes/log_stripping/strip_log_display_particles with storage overly_realistic:temp_values

# -> Reset time
scoreboard players set @s OverlyRealistic.Player.LogStripTime 0