
# -> If basket already has additionals of base type then return
execute if entity @s[tag=OverlyRealistic.Block.Basket_Status_HasAdditionalsBase] run \
    return fail

# -> Advancement
execute on target run \
    advancement grant @s only overly_realistic:advancements/basket_uses/tanned
execute on target run \
    advancement grant @s only overly_realistic:advancements/stone_age/tanned

# -> Edit water
execute on passengers \
    if entity @s[tag=OverlyRealistic.Block.Basket_IsWater] run \
        item modify entity @s contents overly_realistic:basket_waters/solutions/set_tannin_solution

# -> Tag ent
tag @s add OverlyRealistic.Block.Basket_Status_HasTanninSolutionBase
tag @s add OverlyRealistic.Block.Basket_Status_HasAdditionalsBase

# -> Remove items
function overly_realistic:general/custom_blocks/basket/interactions/int_remove_all_items_no_drop
