
# -> Progress 15 : setting part 8 clay, progress 2

# -> If player does not have the right materials then return
execute unless items entity 00000001-0000-002b-0000-00010000002b contents #planks run \
    return fail

# -> If crafting table can't be placed in the current block then return
execute unless block ~ ~ ~ #overly_realistic:spear_can_passthrough run \
    return fail

# -> Add to progress
scoreboard players add @s OverlyRealistic.General.ArbitraryData 1

# -> Set success
scoreboard players set #or.item_success OverlyRealistic.General.ArbitraryData 1

# -> Sound
playsound block.wood.place block @a ~ ~ ~ 0.6 1

# -> Remove displays
execute on passengers run \
    kill @s

# -> Particle
particle minecraft:cloud ~ ~ ~ 0.3 0.3 0.3 0.1 10 normal @a

# -> Set crafting table
setblock ~ ~ ~ crafting_table

# -> Remove interaction
kill @s
