
# -> Untag interaction
tag @s remove OverlyRealistic.Block.ClayMold_TempMold

# -> Rotate display
execute on passengers \
    at @s \
    facing entity @p[tag=OverlyRealistic.Player.PlacedCustomBlock,distance=..16] feet run \
        rotate @s ~ 0

# -> Give ID
execute store result score @s OverlyRealistic.General.ArbitraryData run \
    scoreboard players add #or.clay_mold_id_global OverlyRealistic.General.ArbitraryData 1

# -> Assign data
data modify entity @s data.mold_shape_dialog set value \
    {\
        square_0: 0b, square_1: 0b, square_2: 0b, \
        square_3: 0b, square_4: 0b, square_5: 0b, \
        square_6: 0b, square_7: 0b, square_8: 0b, \
    }

scoreboard players set @s OverlyRealistic.World.ClayMoldSquare_0 0
scoreboard players set @s OverlyRealistic.World.ClayMoldSquare_1 0
scoreboard players set @s OverlyRealistic.World.ClayMoldSquare_2 0
scoreboard players set @s OverlyRealistic.World.ClayMoldSquare_3 0
scoreboard players set @s OverlyRealistic.World.ClayMoldSquare_4 0
scoreboard players set @s OverlyRealistic.World.ClayMoldSquare_5 0
scoreboard players set @s OverlyRealistic.World.ClayMoldSquare_6 0
scoreboard players set @s OverlyRealistic.World.ClayMoldSquare_7 0
scoreboard players set @s OverlyRealistic.World.ClayMoldSquare_8 0
