
# -> Reset adv trigger
advancement revoke @s only overly_realistic:player/player_ride_equidae

# -> Remove skilled buffs
execute on vehicle run \
    function overly_realistic:players/wisdom/equitation/actions/remove_entity_buffs

# --> Add skilled buffs

# -> If player does not have high enough skill then return
execute unless score @s OverlyRealistic.Player.WisdomStats.Equitation matches 1.. run \
    return fail

# -> Add level 1 buff
execute on vehicle run \
    attribute @s armor modifier add overly_realistic:equitation_buffs 0.25 add_multiplied_total

# -> If player does not have high enough skill then return
execute unless score @s OverlyRealistic.Player.WisdomStats.Equitation matches 2.. run \
    return fail

# -> Add level 2 buff
execute on vehicle run \
    attribute @s movement_speed modifier add overly_realistic:equitation_buffs 0.25 add_multiplied_total

# -> If player does not have high enough skill then return
execute unless score @s OverlyRealistic.Player.WisdomStats.Equitation matches 3.. run \
    return fail

# -> Add level 3 buff
execute on vehicle run \
    attribute @s jump_strength modifier add overly_realistic:equitation_buffs 0.25 add_multiplied_total

# -> If player does not have high enough skill then return
execute unless score @s OverlyRealistic.Player.WisdomStats.Equitation matches 4.. run \
    return fail

# -> Add level 4 buffs
execute on vehicle run \
    function overly_realistic:players/wisdom/equitation/actions/level_4_buffs

# -> If player does not have high enough skill then return
execute unless score @s OverlyRealistic.Player.WisdomStats.Equitation matches 5.. run \
    return fail

# -> Add level 5 buffs
execute on vehicle run \
    function overly_realistic:players/wisdom/equitation/actions/level_5_buffs
