
# -> Frog spawning
execute if biome ~ ~ ~ #overly_realistic:random_event_checks/frog_can_spawn_in \
    if predicate overly_realistic:world/random_events/rand_event_2400t_rng run \
        return run \
            summon frog ~ ~ ~ {Tags:["OverlyRealistic.Animal.FrogSpawnedFromRandomEvent","OverlyRealistic.Animal.AnimalSpawnedFromRandomEvent"]}

# -> Spider spawning
execute if biome ~ ~ ~ #overly_realistic:random_event_checks/spider_can_spawn_in run \
    return run \
        function overly_realistic:general/random_events/random_event_2400t/create_spider

# -> Parrot spawning
execute if biome ~ ~ ~ #is_forest run \
    summon parrot ~ ~ ~ {Tags:["OverlyRealistic.Animal.ParrotSpawnedFromRandomEvent","OverlyRealistic.Animal.AnimalSpawnedFromRandomEvent"]}

# -> Moss growth
execute if block ~ ~-1 ~ cobblestone run \
    return run \
        setblock ~ ~-1 ~ mossy_cobblestone

execute if block ~ ~-1 ~ stone_bricks run \
    return run \
        setblock ~ ~-1 ~ mossy_stone_bricks

# -> Silverfish infestation
execute if block ~ ~-1 ~ #overly_realistic:silverfish_can_infest \
    positioned ~ ~-1 ~ run \
        return run \
            function overly_realistic:general/random_events/random_event_2400t/silverfish_infest

execute if block ~ ~-25 ~ #overly_realistic:silverfish_can_infest \
    positioned ~ ~-25 ~ run \
        function overly_realistic:general/random_events/random_event_2400t/silverfish_infest

execute if block ~ ~-50 ~ #overly_realistic:silverfish_can_infest \
    positioned ~ ~-50 ~ run \
        function overly_realistic:general/random_events/random_event_2400t/silverfish_infest
