
# -> Add to campfire fire time (@NOTE: This can be optimized)
execute if items entity @s contents #overly_realistic:adds_to_campfires_0 \
    align xyz \
    positioned ~0.5 ~0.5 ~0.5 run \
        scoreboard players add @n[type=marker,tag=OverlyRealistic.CampfireBlock] OverlyRealistic.World.CampfireFireTime 8
execute if items entity @s contents #overly_realistic:adds_to_campfires_1 \
    align xyz \
    positioned ~0.5 ~0.5 ~0.5 run \
        scoreboard players add @n[type=marker,tag=OverlyRealistic.CampfireBlock] OverlyRealistic.World.CampfireFireTime 50
execute if items entity @s contents #overly_realistic:adds_to_campfires_2 \
    align xyz \
    positioned ~0.5 ~0.5 ~0.5 run \
        scoreboard players add @n[type=marker,tag=OverlyRealistic.CampfireBlock] OverlyRealistic.World.CampfireFireTime 200

# -> Set campfire to lit
#execute if block ~ ~ ~ campfire[lit=false] run \
    setblock ~ ~ ~ campfire[lit=true]

# -> Sound
playsound minecraft:block.blastfurnace.fire_crackle block @a ~0.5 ~0.5 ~0.5 1 2

# -> Particle
particle minecraft:campfire_signal_smoke ~0.5 ~0.5 ~0.5 0 0.4 0 0.01 10 normal @a
particle lava ~0.5 ~0.5 ~0.5 0 0.2 0 0.1 2 normal @a

# -> Remove one stick
item modify entity @s contents overly_realistic:multipurpose/remove_one_item
