title @a title [{"text":"Ravager Beast","color":"#9b0000","bold":true}]
title @a subtitle [{"text":"The Living Siege Weapon","color":"#988c89","bold":true}]
playsound entity.wither.spawn master @a[distance=..200] ~ ~ ~ 1 0.5 1
summon ravager ~ ~50 ~ {DeathLootTable:"kiwi2:entities/10_point",PersistenceRequired:1b,Health:500f,Tags:["wave_mob","ravager_beast","boss"],Passengers:[{id:"minecraft:slime",DeathLootTable:"",Silent:1b,Invulnerable:1b,DeathTime:400,NoAI:0b,Health:9999999f,Size:0,Tags:["boss_check","knight_no_taunt","border_no_tp"],active_effects:[{id:"minecraft:invisibility",amplifier:1,duration:199999980,show_particles:0b},{id:"minecraft:resistance",amplifier:255,duration:199999980,show_particles:0b}],attributes:[{id:"minecraft:max_health",base:9999999},{id:"minecraft:scale",base:0.01}]}],attributes:[{id:"minecraft:armor",base:10},{id:"minecraft:attack_damage",base:12},{id:"minecraft:follow_range",base:100},{id:"minecraft:knockback_resistance",base:1},{id:"minecraft:max_health",base:500},{id:"minecraft:movement_speed",base:0.25},{id:"minecraft:explosion_knockback_resistance",base:1},{id:"scale",base:1.6},{id:"attack_knockback",base:3.5}]}
spreadplayers 0 0 1 20 false @e[type=ravager,tag=wave_mob,tag=ravager_beast]
execute at @e[type=ravager,tag=ravager_beast,tag=boss,limit=1] run particle dust_pillar{block_state:stone} ~ ~1 ~ 5 0 5 0.2 250
execute at @e[type=ravager,tag=ravager_beast,tag=boss,limit=1] run particle poof ~ ~1 ~ 1 1 1 1 250
execute at @e[type=ravager,tag=ravager_beast,tag=boss,limit=1] run playsound minecraft:entity.ravager.roar master @a ~ ~ ~ 10000 0
execute at @e[type=ravager,tag=ravager_beast,tag=boss,limit=1] run playsound entity.wither.break_block master @a ~ ~ ~ 10000 0
scoreboard players set world Boss_Death_Check 1
bossbar add boss_health {"bold":true,"color":"#9b0000","text": "Ravager Beast"}
bossbar set boss_health name {"bold":true,"color":"#9b0000","text": "Ravager Beast"}
bossbar set boss_health visible true
bossbar set boss_health players @a
bossbar set boss_health color red
bossbar set boss_health style notched_12
bossbar set boss_health max 500

# Ravager Beast
# Health = 250
# Atk Dmg = 12
# Movement Speed = 0.25
# Armor = 10
# Skills:
# Roars, damages surrounding and throws players (/damage, summon wind charge)
# Stops for a moment then charges in a straight line (/summon armor_stand, tp in place looking at the armor stand, /tp ^ ^ ^0.1 spam)
# Summons Pillagers & Vindicators to help