bossbar set daytime max 200
execute in kiwi2:limitbreak_run_dimension run forceload add -50 -50 50 50

schedule function kiwi2:run_dimension/platforms/clear_outer_platforms 20t

execute store result score world ArenaRoll run random value 1..2

# Forest Arena
execute in kiwi2:limitbreak_run_dimension if score world ArenaRoll matches 1 run schedule function kiwi2:run_dimension/platforms/forest_platform/chunk_center 10t
execute in kiwi2:limitbreak_run_dimension if score world ArenaRoll matches 1 run schedule function kiwi2:run_dimension/platforms/forest_platform/main 20t

# Desert Arena
execute in kiwi2:limitbreak_run_dimension if score world ArenaRoll matches 2 run schedule function kiwi2:run_dimension/platforms/desert_platform/chunk_center 10t
execute in kiwi2:limitbreak_run_dimension if score world ArenaRoll matches 2 run schedule function kiwi2:run_dimension/platforms/desert_platform/main 20t

title @a times 0 1000 0
title @a title {"text": "|| STANDBY ||","color": "red","bold": true}
title @a subtitle {"text": "...BUILDING ARENA...","color": "#da5757","bold": true}
spreadplayers 0 0 0 25 false @a
execute in kiwi2:limitbreak_run_dimension run kill @e[type=!player,distance=..9999]
worldborder set 50
execute in kiwi2:limitbreak_run_dimension run summon skeleton 0 2 0 {Silent:1b,DeathTime:20,NoAI:1b,Health:1f,Tags:["limitbreak_starting_mob","knight_no_taunt","border_no_tp"],Passengers:[{id:"minecraft:text_display",billboard:"vertical",alignment:"center",Tags:["controller_mob","limitbreak_starting_mob"],transformation:{left_rotation:[0f,0f,0f,1f],right_rotation:[0f,0f,0f,1f],translation:[0f,0.5f,0f],scale:[1f,1f,1f]},text:'{"bold":true,"color":"red","text":">> ATTACK <<"}'}],ArmorItems:[{},{},{},{id:"minecraft:player_head",count:1,components:{"minecraft:profile":{properties:[{name:"textures",value:"eyJ0ZXh0dXJlcyI6eyJTS0lOIjp7InVybCI6Imh0dHA6Ly90ZXh0dXJlcy5taW5lY3JhZnQubmV0L3RleHR1cmUvNDcxYmMyNzI0NjYwYTQ5MTkzN2JiNzZlMDFlZGMzZGJiYjA1ZTEwNGJmNzZkZTIxM2QyYmE4N2RmYjBkMDRkIn19fQ=="}]}}}],active_effects:[{id:"minecraft:invisibility",amplifier:1,duration:1999980,show_particles:0b}],attributes:[{id:"minecraft:max_health",base:1}],DeathLootTable:""}
