title @a title [{"text":"Malformed Warden","color":"#5c8191","bold":true}]
title @a subtitle [{"text":"The Incomplete Blind Watcher","color":"#007ca2","bold":true}]
playsound entity.wither.spawn master @a[distance=..200] ~ ~ ~ 1 0.5 1
summon warden ~ ~50 ~ {Silent:1b,DeathLootTable:"kiwi2:entities/10_point",PersistenceRequired:1b,Health:250f,Tags:["wave_mob","malformed_warden","boss"],Passengers:[{id:"minecraft:slime",DeathLootTable:"",Silent:1b,Invulnerable:1b,DeathTime:400,NoAI:0b,Health:9999999f,Size:0,Tags:["boss_check","knight_no_taunt","border_no_tp"],active_effects:[{id:"minecraft:invisibility",amplifier:1,duration:199999980,show_particles:0b},{id:"minecraft:resistance",amplifier:255,duration:199999980,show_particles:0b}],attributes:[{id:"minecraft:max_health",base:9999999},{id:"minecraft:scale",base:0.01}]}],attributes:[{id:"minecraft:armor",base:10},{id:"minecraft:attack_damage",base:7.5},{id:"minecraft:follow_range",base:100},{id:"minecraft:knockback_resistance",base:0.75},{id:"minecraft:max_health",base:250},{id:"minecraft:movement_speed",base:0.2},{id:"scale",base:0.75}],Brain:{memories:{"minecraft:dig_cooldown":{value:{},ttl:1200L}}}}
spreadplayers 0 0 1 20 false @e[type=warden,tag=wave_mob,tag=malformed_warden]
execute at @e[type=warden,tag=malformed_warden,tag=boss,limit=1] run particle sculk_charge_pop ~ ~1 ~ 1 1 1 0.2 250
execute at @e[type=warden,tag=malformed_warden,tag=boss,limit=1] run particle sculk_soul ~ ~ ~ 10 0 10 0.2 500
execute at @e[type=warden,tag=malformed_warden,tag=boss,limit=1] run playsound minecraft:entity.warden.emerge master @a ~ ~ ~ 10000 0.75
execute at @e[type=warden,tag=malformed_warden,tag=boss,limit=1] run playsound minecraft:entity.warden.roar master @a ~ ~ ~ 10000 1.2
execute at @e[type=warden,tag=malformed_warden,tag=boss,limit=1] run playsound minecraft:entity.fox.screech master @a ~ ~ ~ 10000 0
scoreboard players set world Boss_Death_Check 1
bossbar add boss_health {"bold":true,"color":"#5c8191","text": "Malformed Warden"}
bossbar set boss_health name {"bold":true,"color":"#5c8191","text": "Malformed Warden"}
bossbar set boss_health visible true
bossbar set boss_health players @a
bossbar set boss_health color blue
bossbar set boss_health style notched_6
bossbar set boss_health max 250

# Malformed Warden
# Health = 250
# Atk Dmg = 7.5
# Movement Speed = 0.1
# Armor = 10
# Skills:
# Roar and throw players, (/damage and summon wind charge)
# Summon sculk zombies
# 