kill @e[type=#colosseum_of_fools:fireball,predicate=colosseum_of_fools:ss/speed0,predicate=colosseum_of_fools:in_colosseum]
tag @e[type=#colosseum_of_fools:slime,predicate=colosseum_of_fools:in_colosseum,tag=jjc_spawn,nbt=!{DeathLootTable:"colosseum_of_fools:mob"}] remove jjc_spawn
execute as @e[type=#colosseum_of_fools:mob,tag=jjc_mob,nbt={active_effects:[{id:"minecraft:glowing"}]}] at @s on passengers run data merge entity @s[type=#colosseum_of_fools:marker] {Glowing:1b}
execute as @e[type=#colosseum_of_fools:mob,tag=jjc_mob,nbt=!{active_effects:[{id:"minecraft:glowing"}]}] at @s on passengers run data merge entity @s[type=#colosseum_of_fools:marker] {Glowing:0b}

execute as @e[type=#colosseum_of_fools:neutral_mobs,tag=jjc_mob,nbt={AngerTime:0}] at @s run data modify entity @s AngryAt set from entity @p[predicate=colosseum_of_fools:survive,tag=jjc_p] UUID
execute as @e[type=#colosseum_of_fools:neutral_mobs,tag=jjc_mob,nbt={AngerTime:0}] at @s run data modify entity @s AngerTime set value 100

execute as @e[type=marker,tag=jjc_jjc] at @s positioned ~ ~ ~ as @e[type=#colosseum_of_fools:spider,distance=15..18,predicate=colosseum_of_fools:ss/spider] at @s facing entity @n[distance=..200,tag=jjc_jjc] feet run tp @s ^ ^ ^0.1
execute if entity @e[type=vex,tag=jjc_vex_big,predicate=colosseum_of_fools:ss/target] run function colosseum_of_fools:ss/vex/vex3/1
execute if entity @e[type=ghast,tag=jjc_mob] run function colosseum_of_fools:ss/ghast/main
execute if entity @e[type=enderman,tag=jjc_lhss] run function colosseum_of_fools:ss/enderman/main
execute if entity @e[type=zombie,tag=jjc_lhzs] run function colosseum_of_fools:ss/lhzs/1
execute if entity @e[type=silverfish,tag=jjc_copperfish] run function colosseum_of_fools:ss/copperfish/1
execute if entity @e[type=zombie,tag=jjc_copperfish_tamer,predicate=colosseum_of_fools:ss/player] run function colosseum_of_fools:ss/copperfish/tamer/1
execute if entity @e[type=strider,tag=jjc_strider] run function colosseum_of_fools:ss/strider/1
execute if entity @e[type=wither_skeleton,tag=jjc_wither_skeleton] run function colosseum_of_fools:ss/wither_skeleton/main
execute if entity @e[type=evoker,tag=jjc_evoker] run function colosseum_of_fools:ss/evoker/main
execute if entity @e[type=zombie_villager,tag=jjc_grave1] run function colosseum_of_fools:ss/evoker/necromancer/z
execute if entity @e[type=creeper,tag=jjc_crepper] run function colosseum_of_fools:ss/creeper/main
execute if entity @e[type=cave_spider,tag=jjc_brooding_spider,predicate=colosseum_of_fools:ss/player] run function colosseum_of_fools:ss/brooding_spider/1
execute if entity @e[type=vindicator,tag=jjc_vindicator_elite,predicate=colosseum_of_fools:ss/target] run function colosseum_of_fools:ss/vindicator_elite/1
execute if entity @e[type=pillager,tag=jjc_pillager_shotgun,predicate=colosseum_of_fools:ss/target] run function colosseum_of_fools:ss/pillager/shotgun/1
execute if entity @e[type=witch,tag=jjc_witch,predicate=colosseum_of_fools:ss/player] run function colosseum_of_fools:ss/witch/main
execute if entity @e[type=zombie,tag=jjc_frozen_zombie] run function colosseum_of_fools:ss/frozen_zombie/1
execute if entity @e[type=illusioner,tag=jjc_illusioner] run function colosseum_of_fools:ss/illusioner/1
execute if entity @e[type=blaze,tag=jjc_wildfire] run function colosseum_of_fools:ss/wildfire/main
execute if entity @e[type=vindicator,tag=jjc_geomancer] run function colosseum_of_fools:ss/geomancer/1
execute as @e[type=#minecraft:raiders,tag=jjc_mob] on vehicle at @s[nbt={Health:0f}] on passengers run ride @s dismount